OnPlayerClickPlayerTextDraw DE

From SA-MP Wiki

Diese Funktion/Dieses Callback wurde erstmals in SA:MP 0.3e hinzugefügt und funktioniert nicht in älteren Versionen!

Description:

Hinweis

Anders als OnPlayerClickTextDraw wird OnPlayerClickPlayerTextDraw nicht aufgerufen, wenn der Auswahl-Modus mit ESC abgebrochen wird

new PlayerText:gPlayerTextDraw[MAX_PLAYERS];
 
public OnPlayerConnect(playerid)
{
    // Player-TextDraw erstellen
    gPlayerTextDraw[playerid] = CreatePlayerTextDraw(playerid, 10.000000, 141.000000, "MyTextDraw");
    PlayerTextDrawTextSize(playerid, gPlayerTextDraw[playerid], 60.000000, 20.000000);
    PlayerTextDrawAlignment(playerid, gPlayerTextDraw[playerid],0);
    PlayerTextDrawBackgroundColor(playerid, gPlayerTextDraw[playerid],0x000000ff);
    PlayerTextDrawFont(playerid, gPlayerTextDraw[playerid], 1);
    PlayerTextDrawLetterSize(playerid, gPlayerTextDraw[playerid], 0.250000, 1.000000);
    PlayerTextDrawColor(playerid, gPlayerTextDraw[playerid], 0xffffffff);
    PlayerTextDrawSetProportional(playerid, gPlayerTextDraw[playerid], 1);
    PlayerTextDrawSetShadow(playerid, gPlayerTextDraw[playerid], 1);
 
    // TextDraw auswählbar machen
    PlayerTextDrawSetSelectable(playerid, gPlayerTextDraw[playerid], 1);  
 
    // TextDraw dem Spieler zeigen
    PlayerTextDrawShow(playerid, gPlayerTextDraw[playerid]);
    return 1;
}
 
public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    if(newkeys == KEY_SUBMISSION)
    {
        SelectTextDraw(playerid, 0xFF4040AA);
    }
    return 1;
}
 
public OnPlayerClickPlayerTextDraw(playerid, PlayerText:playertextid)
{
    if(playertextid == gPlayerTextDraw[playerid])
    {
         SendClientMessage(playerid, 0xFFFFFFAA, "Du hast auf ein TextDraw geklickt.");
         CancelSelectTextDraw(playerid);
    }
    return 1;
}

Verwandte Funktionen

Die folgenden Funktionen könnten interessant sein, da sie etwas mit dem Callback zu tun haben.

• PlayerTextDrawSetSelectable: Stellt ein, ob ein Player-TextDraw auswählbar ist.

• OnPlayerClickTextDraw: Wird aufgerufen, wenn ein Spieler auf ein TextDraw klickt.

• OnPlayerClickPlayer: Wird aufgerufen, wenn ein Spieler einen anderen auf der Punkteliste anklickt.